#!/usr/bin/perl -w
# NAME: chkrepos.pl
# AIM: Given a directory, search for subdirectories that contain a repository
# 2016-09-12 - Add a date sort to list...
# 24/07/2016 - Removed the DEBUG_ON flag... first release
# 22/11/2015 geoff mclane http://geoffair.net/mperl
use strict;
use warnings;
use File::Basename;  # split path ($name,$dir,$ext) = fileparse($file [, qr/\.[^.]*/] )
use File::stat; # to get the file date
use Cwd;
my $os = $^O;
my $perl_dir = '/home/geoff/bin';
my $PATH_SEP = '/';
my $temp_dir = '/tmp';
if ($os =~ /win/i) {
    $perl_dir = 'C:\GTools\perl';
    $temp_dir = $perl_dir;
    $PATH_SEP = "\\";
}
unshift(@INC, $perl_dir);
require 'lib_utils.pl' or die "Unable to load 'lib_utils.pl' Check paths in \@INC...\n";
# log file stuff
our ($LF);
my $pgmname = $0;
if ($pgmname =~ /(\\|\/)/) {
    my @tmpsp = split(/(\\|\/)/,$pgmname);
    $pgmname = $tmpsp[-1];
}
my $outfile = $temp_dir.$PATH_SEP."temp.$pgmname.txt";
open_log($outfile);

# user variables
my $VERS = "0.0.7 2016-09-12";
###my $VERS = "0.0.6 2016-07-24";
###my $VERS = "0.0.5 2015-11-22";
my $load_log = 0;
my $in_dir = '';
my $verbosity = 0;
my $out_file = '';
my $depth_max = 2;
#                     1   2    3     4
my @repofolders = qw( CVS .svn .git .hg );

# ### DEBUG ###
my $debug_on = 0;
my $def_file = 'F:\Projects';

### program variables
my @warnings = ();
my $cwd = cwd();

sub VERB1() { return $verbosity >= 1; }
sub VERB2() { return $verbosity >= 2; }
sub VERB5() { return $verbosity >= 5; }
sub VERB9() { return $verbosity >= 9; }

sub show_warnings($) {
    my ($val) = @_;
    if (@warnings) {
        prt( "\nGot ".scalar @warnings." WARNINGS...\n" );
        foreach my $itm (@warnings) {
           prt("$itm\n");
        }
        prt("\n");
    } else {
        prt( "\nNo warnings issued.\n\n" ) if (VERB9());
    }
}

sub pgm_exit($$) {
    my ($val,$msg) = @_;
    if (length($msg)) {
        $msg .= "\n" if (!($msg =~ /\n$/));
        prt($msg);
    }
    show_warnings($val);
    close_log($outfile,$load_log);
    exit($val);
}


sub prtw($) {
   my ($tx) = shift;
   $tx =~ s/\n$//;
   prt("$tx\n");
   push(@warnings,$tx);
}

sub process_in_file($) {
    my ($inf) = @_;
    if (! open INF, "<$inf") {
        pgm_exit(1,"ERROR: Unable to open file [$inf]\n"); 
    }
    my @lines = <INF>;
    close INF;
    my $lncnt = scalar @lines;
    prt("Processing $lncnt lines, from [$inf]...\n");
    my ($line,$inc,$lnn);
    $lnn = 0;
    foreach $line (@lines) {
        chomp $line;
        $lnn++;
        if ($line =~ /\s*#\s*include\s+(.+)$/) {
            $inc = $1;
            prt("$lnn: $inc\n");
        }
    }
}

my $total_dirs = 0;
my $total_files = 0;
my $max_depth = 0;
my @folderlist = ();
my %reposfound = ();
my %repofiles = ();
my $inrepocnt = 0;

sub process_in_dir($$);

sub is_repo_folder {
    my ($fdr) = shift;
    my ($tst);
    my $cnt = 0;
    foreach $tst (@repofolders) {
        $cnt++;
        return $cnt if ($tst eq $fdr);
    }
    return 0;
}

sub contains_repo_folder {
    my ($dir) = shift;
    # $dir =~ s/\\/\//g;
    $dir = path_d2u($dir);
    my @arr = split("/",$dir);
    my ($tst,$off);
    foreach $tst (@arr) {
        $off = is_repo_folder($tst);
        return $off if ($off);
    }
    return 0;
}

sub process_in_dir($$) {
    my ($dir,$lev) = @_;
	if ( !opendir( DIR, $dir ) ) {
        prtw("WARNING: Unable to open dir $dir!\n");
        return;
    }
	my @files = readdir(DIR);
	closedir DIR;
    my ($itm,$ff,$sb,$sz,$tm,$ra);
    ut_fix_directory(\$dir);
    my @dirs = ();
    $total_dirs++;
    $sz = scalar @files;
    prt("Processing directory '$dir' ... $sz objects...\n") if ($lev == 0);
    $max_depth = $lev if ($lev > $max_depth);
    my $ir = contains_repo_folder($dir);
    $inrepocnt++ if ($ir);
	foreach $itm (@files) {
        next if ($itm eq '.');
        next if ($itm eq '..');
        $ff = $dir.$itm;
        if (-f $ff) {
            $sz = 0;
            $tm = 0;
            if ($sb = stat($ff)) {
                $sz = $sb->size;
                $tm = $sb->mtime;
                if ($ir) {
                    $repofiles{$dir} = [] if (! defined $repofiles{$dir});
                    $ra = $repofiles{$dir};
                    push(@{$ra},[$ff,$sz,$tm]);
                }
            } else {
                prtw("WARNING: Can NOT stat '$ff'!\n");
            }
            $total_files++;
        } elsif (-d $ff) {
            push(@dirs,$ff);
            if (is_repo_folder($itm)) {
                if ($lev <= 1) {
                    push(@folderlist, $ff);
                    if (defined $reposfound{$itm}) {
                        $reposfound{$itm}++;
                    } else {
                        $reposfound{$itm} = 1;
                    }
                }
            }
        } else {
            prtw("WARNING: Skipping '$itm'! path $dir\n");
        }
    }
    $lev++;
    $itm = 1;
    if ($depth_max > 0) {
        if ($lev > $depth_max) {
            $itm = 0;
        }
    }
    if ($itm) {
        foreach $dir (@dirs) {
            process_in_dir($dir,$lev);
        }
    }
}

sub mycmp_decend_n1 {
   return 1 if (${$a}[1] < ${$b}[1]);
   return -1 if (${$a}[1] > ${$b}[1]);
   return 0;
}

sub mycmp_ascend_n1 {
   return -1 if (${$a}[1] < ${$b}[1]);
   return  1 if (${$a}[1] > ${$b}[1]);
   return  0;
}

sub show_results() {
    prt("Processed $total_dirs dirs (d=$max_depth), $total_files files...\n");
    my $cnt = scalar @folderlist;
    my @arr = keys %reposfound;
    my ($dir,$rcnt,$ra,$ra2,$tm,$tmm,$m,$ff,$len);
    my $msg = "Found $cnt repos - ";
    if ($cnt) {
        foreach $dir (@arr) {
            $rcnt = $reposfound{$dir};
            $msg .= "$dir $rcnt ";
        }
        prt("$msg\n");
        if (VERB5()) {
            prt(join("\n",@folderlist)."\n");
            prt("$msg\n") if ($cnt > 10);
        }
    } else {
        prt("Ooops, found NO repos using depth 1 from $in_dir\n");
    }
    ##########################################
    my @arr2 = sort keys(%repofiles);
    my $cnt2 = scalar @arr2;
    my $maxdir = 0;
    prt("Found $cnt2 repo files... ($inrepocnt)\n");
    ### prt(join("\n",@arr2)."\n");
    foreach $dir (@arr2) {
        $len = length($dir);
        $maxdir = $len if ($len > $maxdir);
    }
    my $tmm2 = time() + 1;
    my @list = ();
    foreach $dir (@arr2) {
        $ra = $repofiles{$dir};
        $tmm = time() + 1;
        $ff = '';
        foreach $ra2 (@{$ra}) {
            # $sz = ${$ra2}[1];
            $tm = ${$ra2}[2];
            if ($tm < $tmm) {
                $ff = ${$ra2}[0];
                $tmm = $tm;
            }
        }
        push(@list,[$dir,$tmm]);
    }
    @list = sort  mycmp_ascend_n1 @list;
    foreach $ra (@list) {
        $dir = ${$ra}[0];
        $tmm = ${$ra}[1];
        $m = lu_get_YYYYMMDD_UTC($tmm);
        $dir .= ' ' while (length($dir) < $maxdir);
        prt("$dir - $m\n");
    }
    prt("$msg\n") if ($cnt > 10);

}

#########################################
### MAIN ###
parse_args(@ARGV);
process_in_dir($in_dir,0);
show_results();
pgm_exit(0,"");
########################################

sub need_arg {
    my ($arg,@av) = @_;
    pgm_exit(1,"ERROR: [$arg] must have a following argument!\n") if (!@av);
}

sub parse_args {
    my (@av) = @_;
    my ($arg,$sarg);
    my $verb = VERB2();
    while (@av) {
        $arg = $av[0];
        if ($arg =~ /^-/) {
            $sarg = substr($arg,1);
            $sarg = substr($sarg,1) while ($sarg =~ /^-/);
            if (($sarg =~ /^h/i)||($sarg eq '?')) {
                give_help();
                pgm_exit(0,"Help exit(0)");
            } elsif ($sarg =~ /^v/) {
                if ($sarg =~ /^v.*(\d+)$/) {
                    $verbosity = $1;
                } else {
                    while ($sarg =~ /^v/) {
                        $verbosity++;
                        $sarg = substr($sarg,1);
                    }
                }
                $verb = VERB2();
                prt("Verbosity = $verbosity\n") if ($verb);
            } elsif ($sarg =~ /^l/) {
                if ($sarg =~ /^ll/) {
                    $load_log = 2;
                } else {
                    $load_log = 1;
                }
                prt("Set to load log at end. ($load_log)\n") if ($verb);
            } elsif ($sarg =~ /^o/) {
                need_arg(@av);
                shift @av;
                $sarg = $av[0];
                $out_file = $sarg;
                prt("Set out file to [$out_file].\n") if ($verb);
            } else {
                pgm_exit(1,"ERROR: Invalid argument [$arg]! Try -?\n");
            }
        } else {
            if (length($in_dir) > 0) {
                pgm_exit(1,"Error: Already have '$in_dir'! What is this '$arg'?\n");
            }
            $in_dir = $arg;
            prt("Set input to [$in_dir]\n") if ($verb);
            if (! -d $in_dir) {
                pgm_exit(1,"ERROR: Unable to find directory [$in_dir]! Check name, location...\n");
            }
        }
        shift @av;
    }

    if ($debug_on) {
        prtw("WARNING: DEBUG is ON!\n");
        if (length($in_dir) ==  0) {
            $in_dir = $def_file;
            prt("Set DEFAULT input to [$in_dir]\n");
        }
    }
    if (length($in_dir) ==  0) {
        pgm_exit(1,"ERROR: No input files found in command!\n");
    }
    if (! -d $in_dir) {
        pgm_exit(1,"ERROR: Unable to find directory [$in_dir]! Check name, location...\n");
    }
}

sub give_help {
    prt("$pgmname: version $VERS\n");
    prt("Usage: $pgmname [options] in-dir\n");
    prt("Options:\n");
    prt(" --help  (-h or -?) = This help, and exit 0.\n");
    prt(" --verb[n]     (-v) = Bump [or set] verbosity. def=$verbosity\n");
    prt(" --load        (-l) = Load LOG at end. ($outfile)\n");
    prt(" --out <file>  (-o) = Write output to this file.\n");
    prt("\n");
    prt(" Given in imput directory, search for all sub-directories that have a\n");
    prt(" known repo directory, like ".join(", ",@repofolders).", and list.\n");
}

# eof - chkrepos.pl